Cours BARDON - Microsoft Office
ACCUEIL
• Télécharger • Imprimer EXCEL 2003
SOMMAIRE

Excel 03/ Chap 8 - LES FONCTIONS

EXCEL propose plus de 300 fonctions, utilisables dans les formules.

Si la fonction est en début de formule, elle doit être précédée du signe égal.
Exemple : la formule =MAINTENANT() renvoie la date et l'heure courantes. Elargissez la colonne si elle est trop étroite (s'il y a affichage de dièses).

En cours de saisie, une fonction peut être juxtaposée à un texte grâce à l'esperluette &. Exemple :
Sélectionnez la plage B2:C6. Saisissez un nombre dans chaque cellule, validez après chaque saisie en appuyant sur Tab.
Dans la cellule D2, écrivez la formule ="Le résultat est " &SOMME(B2:C2).
Les références étant relatives dans cet exemple, on peut recopier la formule par cliqué-glissé jusqu'en D6 (ou plus rapidement en double-cliquant sur la poignée).

1. ARGUMENTS

Sauf quelques rares exceptions, une fonction requièrent des données, appelées arguments, pour retourner un résultat.

Les arguments sont placés entre parenthèses. On place des parenthèses même en l'absence d'argument pour indiquer qu'il s'agit d'une fonction (et non d'un nom de cellule).
Quand il y a plusieurs arguments, ils sont séparés par un point-virgule.

Exemples de formules utilisant des fonctions qui ont divers nombres et types d'arguments

Fonction sans argument

La formule =AUJOURDHUI() renvoie la date courante.
La formule =ALEA() renvoie une valeur aléatoire, qui n'est jamais la même, entre 0 et 1.

Fonctions avec un argument

La formule =MOYENNE(3:3) renvoie la moyenne des valeurs de la ligne 3 (les valeurs non numériques sont ignorées).
La formule =ENT(SOMME(E6:G8)) renvoie la partie entière de la somme des valeurs de la plage E6:G8.

Fonction avec deux arguments

La formule =DROITE($H$6;4) renvoie les 4 derniers caractères du texte contenu dans la cellule H6.
La référence étant absolue, le texte de référence restera le même, quelle que soit la cellule d'écriture de la formule.

Fonction avec quatre arguments

La formule =SOMME(5;B1:B6;C3;NoErables) renvoie la somme de la constante 5, des valeurs de la plage B1:B6, de la valeur de la cellule C3 et de la valeur des cellules de l'ensemble nommé NoErables.
La fonction SOMME peut recevoir de 1 à 30 arguments.

Comme ces exemples l'illustrent, un argument peut être une constante, la référence d'une cellule, les références d'une plage, un nom attribué ou une autre fonction.

2. RECHERCHE ET INSERTION D'UNE FONCTION

Pour utiliser une fonction dans une formule, deux cas se présentent :

soit, bien que sachant ce que vous voulez faire, vous ignorez le nom de la fonction à utiliser.
Il vous faut alors passer par la fenêtre "Insérer une fonction" (voir le paragraphe ci-après Pour rechercher, puis insérer une fonction) ;
soit vous connaissez le nom de la fonction. Vous pouvez alors directement le saisir.
Une info-bulle vous aidera si besoin pour l'écriture des arguments (Cf. paragraphe Saisie directe).

Pour rechercher, puis insérer une fonction, procédez ainsi :

Sélectionnez la cellule qui contiendra le résultat ;
Dans la barre de formule, cliquez sur le bouton "Insérer une fonction", d'icône f_x (f est l'initiale de fonction et x symbolise un argument).
Le signe égal s'affiche aussitôt dans la cellule résultat et la fenêtre "Insérer une fonction" s'affiche .
Recherche de la fonction
- Soit vous saisissez dans la zone "Rechercher une fonction" ce que vous souhaitez faire. Par exemple : calculer le reste d'une division), puis Entrée.
  EXCEL propose alors un choix restreint de fonctions. Dans l'exemple, il est notamment proposé MOD ;
- Soit vous sélectionnez dans le menu déroulant une catégorie de fonctions, parmi la dizaine de catégories proposées.
  Selon la catégorie choisie, une liste de fonctions s'affiche dans la zone centrale.
Sélectionnez une fonction.
La sélection d'une fonction par simple clic affiche sa syntaxe, en particulier sur ses arguments, ainsi qu'un bref descriptif. Le lien hypertexte Aide donne de plus amples informations.
Validez le choix par OK, ou en double-cliquant sur la fonction. Ou bien saisissez le nom de la fonction dans la zone centrale, puis validez.
Une nouvelle fenêtre "Arguments de la fonction" s'affiche. Saisissez les arguments, ou gardez ceux qui sont éventuellement proposés.
Le résultat s'affiche en bas de la fenêtre au fur et à mesure de la saisie des arguments.
Validez. La validation insère la parenthèse fermante.

La fonction dotée de ses arguments est insérée dans la formule, et le résultat est affiché dans la cellule.

3. SAISIE DIRECTE

Si vous connaissez le nom exact de la fonction que vous souhaitez insérer dans une formule, vous pouvez la saisir directement.
Juste après la saisie de la première parenthèse ouvrante, une info-bulle affiche le nom de la fonction et les arguments requis.
Les arguments cités entre crochets sont facultatifs.

En cliquant sur le nom de la fonction, l'aide sur cette fonction apparaît.
En cliquant sur un argument, l'argument correspondant dans la cellule est sélectionné.

L'insertion des arguments peut être effectuée soit par saisie, soit par sélection de cellules. Fermez la parenthèse, puis validez. Le résultat de la fonction s'affiche dans la cellule.

4. EXEMPLES

Bouton somme automatique

Sélectionnez la cellule qui contiendra le résultat. En cliquant sur le bouton

de la barre d'outils Standard, on obtient rapidement la somme de cellules sélectionnées.
Bien que son info-bulle soit "Somme automatique", son menu déroulant propose quatre autres fonctions souvent utilisées : Moyenne, Compteur, Max et Min.
La fonction Compteur totalise le nombre de cellules contenant des valeurs numériques de chaque argument, en ajoutant éventuellement le nombre d'arguments qui sont des valeurs numériques.
Le sous-menu "Autres fonctions" affiche la fenêtre "Insérer une fonction" qui permet d'accéder à toutes les autres fonctions d'EXCEL.

La fonction SI

Définition

Une formule contenant la fonction SI est appelée une formule conditionnelle. Cette fonction est très utilisée.
La fonction SI renvoie un résultat qui diffère selon qu'une expression, appelée "Test", est vraie ou fausse (expression dite logique) :
SI (Test;alors Résultat_si_Test_vrai;sinon Résultat_si_Test_faux)

L'expression Test contient nécessairement un opérateur logique : égal = , supérieur > , supérieur ou égal >= , inférieur <, inférieur ou égal <= .
Les deux résultats suivants ("résultat si test vrai" et "résultat si test faux") peuvent contenir des fonctions, des calculs, différents types d'expression (Date, Texte, Pourcentage...) etc.

La fonction SI peut n'être dotée que de deux arguments.
Exemple : la formule =SI(E6="Jaune";"la couleur est jaune") affiche FAUX si la valeur de E6 n'est pas le mot jaune (en minuscules ou en majuscules, EXCEL ne reconnaissant pas la casse).

Autres exemples de fonctions conditionnelles

=SI(A2>B1;"la valeur est supérieure à "&B1)
L'esperluette & permet de juxtaposer la valeur de B1 au texte.

=SI(NBCAR(D5)>NBCAR(D4);"D5 contient " &(NBCAR(D5)-NBCAR(D4))&" caractères de plus que D4")
La fonction NBCAR renvoie le nombre de caractères du texte passé en argument.

="Le résultat est "&SI(T9>=U6; " supérieur ou égal" ;" inférieur")
L'esperluette & permet de juxtaposer le texte à la fonction.

=SI(G18>DATE(2010;4;17);"La date est dépassée")
Il est possible de comparer des textes littéraires (ordre alphabétique) ou des dates comme dans cet exemple. La date la plus récente est la plus grande.

=SI(ET(B3=5;B3>A3);"5 est strictement supérieur à "&A3)
Opérateur ET : ET(B3=5;B3>A3) signifie B3=5 et B3>A3
L'opérateur OU a la même syntaxe :
=SI(OU(C2=3;C2=4;C2=5);"La valeur de C2 est 3, 4 ou 5")

Une fonction peut en imbriquer d'autres, sept niveaux sont possibles.
=SI(A2<>C2;SI(A2=D2;REPT(A2;4);REPT(C2;6)))
Dans ce dernier exemple, il y a trois niveaux d'imbrication : SI SI REPT.
La fonction REPT affiche la répétition du texte passé en 1er argument, en nombre égal à la valeur du 2ème argument.

Autres exemples

EXACT
EXACT(texte1;texte2)
La fonction renvoie la valeur VRAI si les deux textes spécifiés sont identiques, sinon elle renvoie FAUX. La casse est considérée, la mise en forme est ignorée.

MAJUSCULE et MINUSCULE
MAJUSCULE(texte) et MINUSCULE(texte)
Chaque fonction convertit le texte passé en argument dans la casse spécifiée.

SUPPRESPACE
SUPPRESPACE(texte)
La fonction supprime dans le texte spécifié les espaces "de trop".

NB.VIDE
NB.VIDE(plage)
La fonction compte le nombre de cellules vides dans la plage spécifiée.

NB.SI
NB.SI(plage;critère)
La fonction compte le nombre de cellules de la plage donnée, qui répondent au critère spécifié.
Exemples
La formule =NB.SI(B2:C5;"=24") renvoie le nombre de cellules dont la valeur égale 24. Mettez bien les guillemets.
La formule =NB.SI(B2:C5;">="&D1) renvoie en résultat le nombre de cellules de la plage B2:C5 dont la valeur est supérieure à celle de la cellule D1. Positionnez bien les guillemets.